import QtQuick 2.14
import QtQuick.Controls 2.14
import QtQuick.Controls.impl 2.14
import QtQuick.Templates 2.14 as T

T.SpinBox {
    id: control
    from: 0
    value: 110
    to: 1000 * 100
    stepSize: 10
    editable: true
    wheelEnabled : true

    property int decimals: 2
    property int divisor: 100
    property real realValue: value / divisor

    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
                            contentItem.implicitWidth + 2 * padding +
                            up.implicitIndicatorWidth +
                            down.implicitIndicatorWidth)
    implicitHeight: Math.max(implicitContentHeight + topPadding + bottomPadding,
                             implicitBackgroundHeight,
                             up.implicitIndicatorHeight,
                             down.implicitIndicatorHeight)

    padding: 0
    leftPadding: padding + (control.mirrored ? (up.indicator ? up.indicator.width : 0) : (down.indicator ? down.indicator.width : 0))
    rightPadding: padding + (control.mirrored ? (down.indicator ? down.indicator.width : 0) : (up.indicator ? up.indicator.width : 0))

    validator: DoubleValidator {
        bottom: Math.min(control.from, control.to)
        top:  Math.max(control.from, control.to)
    }

    valueFromText: function(text, locale) {
        return Number.fromLocaleString(locale, text) * divisor
    }
    contentItem: TextInput {
        z: 2
        text: Number(value / divisor).toLocaleString(locale, 'f', control.decimals)
        selectByMouse: true
        onActiveFocusChanged: {
            // When we first gain focus, select everything for clearing.
            if (activeFocus) {
                selectAll()
            }
        }
        onEditingFinished: {
            control.focus = false
        }
        
        color: activePalette.text
        selectionColor: activePalette.highlight
        selectedTextColor: activePalette.highlightedText
        horizontalAlignment: Qt.AlignHCenter
        verticalAlignment: Qt.AlignVCenter

        readOnly: !control.editable
        validator: control.validator
        inputMethodHints: Qt.ImhFormattedNumbersOnly

        Rectangle {
            x: 0 - (control.down.indicator ? 1 : 0)
            y: 0
            width: control.width - (control.up.indicator ? control.up.indicator.width - 1 : 0) - (control.down.indicator ? control.down.indicator.width - 1 : 0)
            height: control.height
            visible: control.activeFocus
            color: "transparent"
            border.color: activePalette.highlight
            border.width: 2
        }
    }

    up.indicator: Rectangle {
        x: control.mirrored ? 0 : parent.width - width
        height: parent.height
        implicitWidth: 24
        implicitHeight: 24
        color: control.up.pressed ? activePalette.mid : activePalette.button

        Rectangle {
            x: (parent.width - width) / 2
            y: (parent.height - height) / 2
            width: parent.width / 3
            height: 2
            color: enabled ? activePalette.buttonText : activePalette.mid
        }
        Rectangle {
            x: (parent.width - width) / 2
            y: (parent.height - height) / 2
            width: 2
            height: parent.width / 3
            color: enabled ? activePalette.buttonText : activePalette.mid
        }
    }

    down.indicator: Rectangle {
        x: control.mirrored ? parent.width - width : 0
        height: parent.height
        implicitWidth: 24
        implicitHeight: 24
        color: control.down.pressed ? activePalette.mid : activePalette.button

        Rectangle {
            x: (parent.width - width) / 2
            y: (parent.height - height) / 2
            width: parent.width / 3
            height: 2
            color: enabled ? activePalette.buttonText : activePalette.mid
        }
    }

    background: Rectangle {
        implicitWidth: 120
        color: enabled ? activePalette.dark : activePalette.button
        // border.color: activePalette.button
        // border.width: 3
    }
}